GameStar 1998 November (Bonus)/GAMESTAR11B.ISO/ENCYC99/MM/T620277A.DCR/Scripts_3_Class BlendSlidThing.ls

Text File | 1998-06-29 | 1.6 KB | 90 lines

property Slider, slidSprite, slidFirst, slidLast, minSlide, maxSoftSlide, currentSlid, newTicks

on softSlide me, xInt
  set tempTicks to the ticks
  if tempTicks > newTicks then
    set slideHere to nearJump(me, xInt)
    hardSlide(me, slideHere)
    set newTicks to tempTicks + 6
  end if
end

on hardSlide me, xInt
  set slideThere to bestValue(me, xInt)
  moveSlidThing(me, slideThere)
end

on crankUp me
  hardSlide(me, slidLast)
end

on crankDown me
  hardSlide(me, slidFirst)
end

on getMapInfo me
  return [slidFirst, slidLast]
end

on newPict me, xMember
  set the member of sprite slidSprite to xMember
end

on new me, xSprite
  set slidSprite to xSprite
  puppetSprite(slidSprite, 1)
  set minSlide to 1
  set maxSoftSlide to 1
  return me
end

on setMinSlide me, xInt
  set minSlide to xInt
end

on setMaxSlide me, xInt
  set maxSoftSlide to xInt
end

on linkUp me, xSlider
  initMapInfo(me)
  set Slider to xSlider
end

on updateSlider me
  moveSlidThing(me, currentSlid)
end

on bestValue me, xInt
  set thisValue to xInt
  set thisOff to thisValue mod minSlide
  if thisOff <> 0 then
    set thisValue to thisValue - thisOff
  end if
  return thisValue
end

on nearJump me, xInt
  set slideHere to xInt
  if abs(currentSlid - slideHere) > maxSoftSlide then
    if slideHere < currentSlid then
      set slideHere to currentSlid - maxSoftSlide
    else
      set slideHere to currentSlid + maxSoftSlide
    end if
  end if
  return slideHere
end

on moveSlidThing me, xInt
  set currentSlid to xInt
  set the blend of sprite slidSprite to currentSlid
  reDraw(Slider, xInt)
end

on initMapInfo me
  set slidFirst to 0
  set currentSlid to 50
  set slidLast to 100
end